% Gráfica de Funciones de Bessel de Primer Orden
\documentclass{standalone}
\usepackage[T1]{fontenc}
\usepackage{verbatim, gnuplottex}
\begin{comment}
Este gráfico representa a las funciones de Bessel de primera especie, descritas en la página web http://www.sc.ehu.es/sbweb/fisica3/especial/bessel/bessel.html, las cuales se usan ampliamente, entre otros campos, para el procesamiento de señales, en telecomunicaciones para el análisis de portadora modulada en frecuencia (FM), para el estudio del desplazamiento de ondas electromagnéticas en fibras ópticas y guias de onda cilíndricas y el estudio de la conducción del calor en objetos cilíndricos.
Para trazar este gráfico, se aprovecha el paquete GNUPLOTTEX el cual tiene una biblioteca de funciones donde están las dos primeras funciones de Bessel de Primer Orden, las cuales se pueden manipular matemáticamente sin definir funciones (como ocurre en LaTeX) y un ambiente "gnuplot" donde se introducen las órdenes necesarias en el lenguaje de "gnuplot". Dentro de este ambiente, el símbolo # denota a los comentarios.
\end{comment}
\begin{document}
% Etapa de graficación. Las opciones del ambiente "gnuplot" indican el "terminal" usado y las opciones dentro de éste.
\begin{gnuplot}[terminal=cairolatex, terminaloptions={color solid font ",10" }]
set key top right box # Leyendas en la esquina superior derecha
set key width 0 # Ancho de la Caja de Leyendas
set key opaque # Caja de leyendas opaca
set grid # Muestra la rejilla del gráfico
set sample 1000 # Cantidad de muestras por cada función
set xr [0:12] # Rango en el eje X, no es necesario definir el rango del eje Y, pero si se desea, se usa la orden "set yr"
set xlabel "Índice de modulación $m$" # Etiqueta del eje X
set ylabel "$J_n(m)$" # Etiqueta del eje Y
# Definición de las funciones. No es necesaria una rutina de definición de funciones:
besj2(x) = 2*1/x * besj1(x) - besj0(x)
besj3(x) = 2*2/x * besj2(x) - besj1(x)
besj4(x) = 2*3/x * besj3(x) - besj2(x)
besj5(x) = 2*4/x * besj4(x) - besj3(x)
besj6(x) = 2*5/x * besj5(x) - besj4(x)
#Definición del color de fondo del gráfico. El color debe estar indicado en letras minúsculas:
# En la orden plot (orden de graficar) se incluyen también lc (color de línea), lw (ancho de línea) y t como texto a incluir en una leyenda. El símbolo "\" indica la continuación de la línea. Con una sola orden plot <función> se grafican todas las funciones, separándolas con comas. Si se continúa con las funciones en las líneas siguientes, se debe usar obligatoriamente el carácter "\" para indicar la continuación de la línea.
plot besj0(x) lc 7 lw 3 t '$J_0(x)$',\
besj1(x) lc 2 lw 3 t '$J_1(x)$',\
besj2(x) lc 4 lw 3 t '$J_2(x)$',\
besj3(x) lc 6 lw 3 t '$J_3(x)$',\
besj4(x) lc 1 lw 3 t '$J_4(x)$',\
besj5(x) lc 3 lw 3 t '$J_5(x)$',\
besj6(x) lc 5 lw 3 t '$J_6(x)$'
\end{gnuplot}
\end{document}
